@echo off
title Установка PureHelper

REM Установка расширения PureHelper.
REM Регистрирует Chrome в PureHelper Chrome Enterprise Core; расширение
REM приезжает облачной политикой из Admin Console. Нужны права администратора.
REM Токен ниже - публичный enrollment-токен PureHelper, как в .pkg.

net session >nul 2>&1
if %errorlevel% equ 0 goto admin

REM Не администратор - перезапускаем этот же файл через UAC.
echo Запрашиваю права администратора...
powershell -NoProfile -Command "Start-Process -FilePath '%~f0' -Verb RunAs"
exit /b

:admin
echo.
echo Установка PureHelper
echo.
echo Если расширение уже загружено вручную через chrome://extensions,
echo сначала удалите его там: Chrome не поставит вторую копию.
echo.
echo Chrome будет закрыт. Вкладки восстановятся при следующем запуске.
echo.
pause

echo Устанавливаю PureHelper...
reg add "HKLM\SOFTWARE\Policies\Google\Chrome" /v CloudManagementEnrollmentToken /t REG_SZ /d 542df1cd-273d-45cd-b9af-b409699d0eec /f >nul
reg add "HKLM\SOFTWARE\WOW6432Node\Policies\Google\Chrome" /v CloudManagementEnrollmentToken /t REG_SZ /d 542df1cd-273d-45cd-b9af-b409699d0eec /f >nul

REM Сначала просим Chrome закрыться сам, чтобы он сохранил вкладки.
tasklist /FI "IMAGENAME eq chrome.exe" 2>nul | find /I "chrome.exe" >nul
if errorlevel 1 goto done
echo Закрываю Chrome...
taskkill /IM chrome.exe >nul 2>&1
timeout /t 6 /nobreak >nul
tasklist /FI "IMAGENAME eq chrome.exe" 2>nul | find /I "chrome.exe" >nul
if errorlevel 1 goto done
taskkill /F /IM chrome.exe /T >nul 2>&1

:done
echo.
echo Готово. Запустите Chrome - расширение появится через 1-2 минуты.
echo Проверка: адрес chrome://management - "браузером управляет организация".
echo.
echo Удалить: файл PureHelper-Uninstall.bat со страницы установки.
echo.
pause